在 AS3中 ，我們可以使用

    [Embed(source="asset.swf", symbol="symbol")]

private var symbolClass:Class;



var symbol:MovieClip = new symbolClass();


  

從藝術(shù)中嵌入一個符號 的SWF 在什么可能是一個代碼構(gòu)建 的SWF 。 這是偉大的，但如果你要嵌入整個 SWF ？

    [Embed(source="asset.swf")]

private var assetClass:Class;



var asset:MovieClip = new assetClass();


  

看起來像它應(yīng)該做的伎倆，但你不能在資產(chǎn)中獲得的任何信息。 這是一個真正的痛苦，因為這是非常令人費解的原因。 我想起了解決這個問題，在過去的工作，并愉快地設(shè)法挖掘一個長期被遺忘的寶藏在我的代碼庫，我想我會分享（已經(jīng)迅速重構(gòu)它以使用AS3-信號，自然）。

    package com.alecmce.util

{

	import org.osflash.signals.Signal;



	import mx.core.MovieClipAsset;



	import flash.display.Loader;

	import flash.display.LoaderInfo;

	import flash.display.MovieClip;

	import flash.events.Event;



	public class UnpackEmbed

	{

		private var _ready:Signal;



		private var _asset:MovieClipAsset;

		private var _content:MovieClip;



		public function UnpackEmbed(assetClass:Class)

		{

			_asset = new assetClass();

			_ready = new Signal(UnpackEmbed);



			var loader:Loader = Loader(_asset.getChildAt(0));

			var info:LoaderInfo = loader.contentLoaderInfo;

			info.addEventListener(Event.COMPLETE, onLoadComplete);

		}



		private function onLoadComplete(event:Event):void

		{

			var info:LoaderInfo = LoaderInfo(event.target);

			info.removeEventListener(Event.COMPLETE, onLoadComplete);



			_content = MovieClip(info.loader.content);

			_ready.dispatch(this);

		}



		public function get content():MovieClip

		{

			return _content;

		}



		public function get ready():Signal

		{

			return _ready;

		}



		public function get asset():MovieClipAsset

		{

			return _asset;

		}

	}

}


  

當(dāng)您嵌入的SWF以這種方式，然后實例化它，閃存莫名其妙密謀建立一個 MovieClipAsset 用 裝載機(jī) 內(nèi)，這將是'加載'已嵌入的內(nèi)容。 內(nèi)容不是立即可用（也可能是有時候，我也遇到過的情況下它不是），所以你必須等待 Event.COMPLETE 被解雇之前，您可以訪問它。 此類公開，通知您當(dāng)內(nèi)容準(zhǔn)備就緒的信號。 它可能可以更嚴(yán)格，例如，包括 在isComplete 標(biāo)志，但它提供我的目的，以下面的方式使用時：

    [Embed(source="asset.swf")]

private var assetClass:Class;



asset = new UnpackEmbed(assetClass);

asset.ready.addOnce(onAssetReady);



private function onAssetReady(asset:UnpackEmbed):void

{

	// now we can access the asset.content!

}
  

[Embed(source="asset.swf")] 使用其中的所有資源